From b058c6fc65e2cdee876aeba71ceaa280fbcd0f9f Mon Sep 17 00:00:00 2001
From: Akshay <nerdy@peppe.rs>
Date: Sat, 17 Apr 2021 22:02:35 +0530
Subject: init

---
 flake.nix | 69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 flake.nix

(limited to 'flake.nix')

diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..271ef18
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,69 @@
+{
+  description = "Latex Project Presentation Template";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs";
+    utils.url = "github:numtide/flake-utils";
+    gitignore = {
+      url = "github:hercules-ci/gitignore";
+      flake = false;
+    };
+  };
+
+  outputs = { self, nixpkgs, utils, gitignore, ... }:
+    utils.lib.eachDefaultSystem (system:
+      let
+        pname = "presentation";
+        version = "0.1.0";
+        pkgs = nixpkgs.legacyPackages."${system}";
+        inherit (import gitignore { inherit (pkgs) lib; }) gitignoreSource;
+        nativeBuildInputs = with pkgs; [
+          (texlive.combine {
+            inherit (texlive)
+              scheme-medium
+              multirow
+              hyperref
+              blindtext
+              etoolbox
+              topiclongtable
+              beamer;
+          })
+          gnumake
+        ];
+        watcher = pkgs.writeScriptBin "watch" ''
+          out=".latexmkout"
+          mkdir "$out"
+          latexmk \
+            -pvc \
+            -outdir="$out" \
+            -pdf \
+            -pdflatex="pdflatex -interaction=nonstopmode" \
+            -use-make ${pname}.tex
+          rm -r "$out"
+        '';
+      in
+      rec {
+        defaultPackage = pkgs.stdenv.mkDerivation {
+          inherit pname version;
+          src = gitignoreSource ./.;
+          buildInputs = nativeBuildInputs;
+          buildPhase = ''
+            latexmk \
+              -pdf \
+              -pdflatex="pdflatex -interaction=nonstopmode" \
+              -use-make ${pname}.tex
+          '';
+          installPhase = ''
+            mkdir -p $out
+            cp ${pname}.pdf $out/
+          '';
+        };
+        apps.watch = {
+          type = "app";
+          program = "${watcher}/bin/watch";
+        };
+        devShell = pkgs.mkShell {
+          nativeBuildInputs = nativeBuildInputs;
+        };
+      });
+}
-- 
cgit v1.2.3