blob: 1fd10a93084db1898a2879a4bd7078479fb33ebe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
{
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
fenix = {
url = "github:nix-community/fenix";
inputs.nixpkgs.follows = "nixpkgs";
};
gitignore = {
url = "github:hercules-ci/gitignore.nix";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs =
{ self
, nixpkgs
, fenix
, gitignore
}:
let
inherit (gitignore.lib) gitignoreSource;
supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
nixpkgsFor = forAllSystems (system:
import nixpkgs {
inherit system;
overlays = [ self.overlay ];
});
chanspec = {
date = "2022-02-06";
channel = "nightly";
sha256 = "oKkTWopCDx4tphzTtRn+zDDtvmIZrL/H44tV2ruSfDw="; # set zeros after modifying channel or date
};
rustChannel = p: (fenix.overlay p p).fenix.toolchainOf chanspec;
in
{
overlay = final: prev: {
statix = with final;
let
pname = "statix";
packageMeta = (lib.importTOML ./bin/Cargo.toml).package;
rustPlatform = makeRustPlatform {
inherit (rustChannel final) cargo rustc;
};
in
rustPlatform.buildRustPackage {
inherit pname;
inherit (packageMeta) version;
src = gitignoreSource ./.;
cargoLock.lockFile = ./Cargo.lock;
buildFeatures = "json";
meta = with lib; {
description = "Lints and suggestions for the Nix programming language";
homepage = "https://git.peppe.rs/languages/statix/about";
license = licenses.mit;
};
};
statix-vim =
with final; vimUtils.buildVimPlugin {
pname = "statix-vim";
version = "0.1.0";
src = ./vim-plugin;
};
};
packages = forAllSystems (system: {
inherit (nixpkgsFor."${system}") statix statix-vim;
});
defaultPackage =
forAllSystems (system: self.packages."${system}".statix);
devShell = forAllSystems (system:
let
pkgs = nixpkgsFor."${system}";
toolchain = (rustChannel pkgs).withComponents [
"rustc"
"cargo"
"rust-std"
"rustfmt"
"clippy"
"rust-src"
];
inherit (fenix.packages."${system}") rust-analyzer;
in
pkgs.mkShell {
nativeBuildInputs = [
pkgs.bacon
pkgs.cargo-insta
rust-analyzer
toolchain
];
RUST_LOG = "info";
RUST_BACKTRACE = 1;
});
apps = forAllSystems
(system:
let
pkgs = nixpkgsFor."${system}";
cachix-push-script = pkgs.writeScriptBin "cachix-push" ''
${pkgs.nixUnstable}/bin/nix build --json \
| ${pkgs.jq}/bin/jq -r '.[].outputs | to_entries[].value' \
| ${pkgs.cachix}/bin/cachix push statix
'';
in
{
cachix-push = {
type = "app";
program = "${cachix-push-script}/bin/cachix-push";
};
}
);
};
}
|
