1 files changed, 101 insertions, 0 deletions

diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..3f416a9
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,101 @@
+{
+  inputs = {
+
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+
+    fenix = {
+      url = "github:nix-community/fenix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    gitignore = {
+      url = "github:hercules-ci/gitignore.nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+  };
+
+  outputs =
+    { self
+    , nixpkgs
+    , fenix
+    , gitignore
+    }:
+    let
+      inherit (gitignore.lib) gitignoreSource;
+
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+      nixpkgsFor = forAllSystems (system:
+        import nixpkgs {
+          inherit system;
+          overlays = [ self.overlay ];
+        });
+
+      chanspec = {
+        date = "2021-12-01";
+        channel = "nightly";
+        sha256 = "DhIP1w63/hMbWlgElJGBumEK/ExFWCdLaeBV5F8uWHc="; # set zeros after modifying channel or date
+      };
+      rustChannel = p: (fenix.overlay p p).fenix.toolchainOf chanspec;
+
+    in
+    {
+
+      overlay = final: prev: {
+
+        prompt = with final;
+          let
+            pname = "prompt";
+            packageMeta = (lib.importTOML ./bin/Cargo.toml).package;
+            rustPlatform = makeRustPlatform {
+              inherit (rustChannel final) cargo rustc;
+            };
+          in
+          rustPlatform.buildRustPackage {
+            inherit pname;
+            inherit (packageMeta) version;
+
+            buildInputs = [
+              final.openssl
+              final.pkgconfig
+            ];
+
+            src = gitignoreSource ./.;
+            cargoLock.lockFile = ./Cargo.lock;
+          };
+
+      };
+
+      packages = forAllSystems (system: {
+        inherit (nixpkgsFor."${system}") prompt;
+      });
+
+      defaultPackage =
+        forAllSystems (system: self.packages."${system}".prompt);
+
+      devShell = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor."${system}";
+          toolchain = (rustChannel pkgs).withComponents [
+            "rustc"
+            "cargo"
+            "rust-std"
+            "rustfmt"
+            "clippy"
+            "rust-src"
+          ];
+          inherit (fenix.packages."${system}") rust-analyzer;
+        in
+        pkgs.mkShell {
+          nativeBuildInputs = [
+            pkgs.bacon
+            rust-analyzer
+            toolchain
+          ];
+          RUST_LOG = "info";
+          RUST_BACKTRACE = 1;
+        });
+
+    };
+}