flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

{
  description = "Latex Project Presentation Template";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    utils.url = "github:numtide/flake-utils";
    gitignore = {
      url = "github:hercules-ci/gitignore";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, utils, gitignore, ... }:
    utils.lib.eachDefaultSystem (system:
      let
        pname = "presentation";
        version = "0.1.0";
        pkgs = nixpkgs.legacyPackages."${system}";
        inherit (import gitignore { inherit (pkgs) lib; }) gitignoreSource;
        nativeBuildInputs = with pkgs; [
          (texlive.combine {
            inherit (texlive)
              scheme-medium
              multirow
              hyperref
              blindtext
              etoolbox
              topiclongtable
              beamer;
          })
          gnumake
        ];
        watcher = pkgs.writeScriptBin "watch" ''
          out=".latexmkout"
          mkdir "$out"
          latexmk \
            -pvc \
            -outdir="$out" \
            -pdf \
            -pdflatex="pdflatex -interaction=nonstopmode" \
            -use-make ${pname}.tex
          rm -r "$out"
        '';
      in
      rec {
        defaultPackage = pkgs.stdenv.mkDerivation {
          inherit pname version;
          src = gitignoreSource ./.;
          buildInputs = nativeBuildInputs;
          buildPhase = ''
            latexmk \
              -pdf \
              -pdflatex="pdflatex -interaction=nonstopmode" \
              -use-make ${pname}.tex
          '';
          installPhase = ''
            mkdir -p $out
            cp ${pname}.pdf $out/
          '';
        };
        apps.watch = {
          type = "app";
          program = "${watcher}/bin/watch";
        };
        devShell = pkgs.mkShell {
          nativeBuildInputs = nativeBuildInputs;
        };
      });
}